;; webid-oidc, implementation of the Solid specification
;; Copyright (C) 2020, 2021  Vivien Kraus

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU Affero General Public License as
;; published by the Free Software Foundation, either version 3 of the
;; License, or (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU Affero General Public License for more details.

;; You should have received a copy of the GNU Affero General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

(define-module (webid-oidc jti)
  #:use-module (ice-9 atomic)
  #:use-module (ice-9 threads)
  #:use-module (srfi srfi-19))

(define-public (make-jti-list)
  (make-atomic-box '()))

(define-public (lookup list jti)
  (if (null? list)
      #f
      (or (string=? (assq-ref (car list) 'jti) jti)
          (lookup (cdr list) jti))))

(define-public (jti-check current-time jti list valid-time)
  (when (date? current-time)
    (set! current-time (date->time-utc current-time)))
  (when (time? current-time)
    (set! current-time (time-second current-time)))
  (let* ((old (atomic-box-ref list))
         (new-entry `((exp . ,(+ current-time valid-time))
                      (jti . ,jti)))
         (new (filter
               (lambda (entry)
                 (let ((exp (assq-ref entry 'exp)))
                   (>= exp current-time)))
               (cons new-entry old))))
    (let ((present? (lookup old jti)))
      (if present?
          #f
          (let ((discarded (atomic-box-compare-and-swap! list old new)))
            (if (eq? discarded old)
                #t
                (jti-check current-time jti list valid-time)))))))