blob: 9d9da0f0bc5101cbc0b1234c38084205843224a7 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
|
(define-module (webid-oidc cache)
#:use-module ((webid-oidc stubs) #:prefix stubs:)
#:use-module (web client)
#:use-module (web request)
#:use-module (web response)
#:use-module (web uri)
#:use-module (ice-9 ftw)
#:use-module (ice-9 receive)
#:use-module (ice-9 optargs)
#:use-module (srfi srfi-19)
#:use-module (rnrs bytevectors))
;; The cache follows the recommendations of
;; https://developer.mozilla.org/en-US/docs/Web/HTTP/Caching
;; In a directory, we dump files, indexed by the hash of the URI, and
;; containing the request, response and response body.
;; We keep only one version of the resource, even with varying
;; headers. If the cache validation fails due to varying headers, we
;; simply drop the old variant and replace it with the new. For things
;; like user agents or accepted language or encoding, you’re not
;; likely to alternate quickly between two values anyway.
;; We’re not very concerned by the cache growing. We provide a cleanup
;; function that will kill a few percents of the cached entries at
;; random, and that you should call with a cron job regularly. It will
;; sometimes drop valid cached entries, but life goes on. By default,
;; each cache update has a 5% chance to trigger the elimination of 5%
;; of the cache.
;; There is a global lock file at the root of the cache, which serves
;; for region locking. Do not remove it!
(define (default-cache-dir)
(let ((xdg-cache-home
(or (getenv "XDG_CACHE_HOME")
(format #f "~a/.cache"))))
(format #f "~a/webid-oidc" xdg-cache-home)))
(define (web-cache-dir dir)
(when (thunk? dir)
(set! dir (dir)))
(string-append dir
"/web-cache/"))
(define (file-name uri dir)
(when (string? uri)
(set! uri (string->uri uri)))
(string-append (web-cache-dir dir)
(stubs:hash 'SHA-256 (uri->string uri))))
(define (lock-file-name dir)
(string-append (web-cache-dir dir) ".lock"))
(define (event? percents)
(<= (* (random:uniform) 100)
percents))
(define*-public (clean-cache
#:key
(percents 5)
(dir default-cache-dir))
(define lock-file (lock-file-name dir))
(define (survives?)
(not (event? percents)))
(define (enter? name stat result)
#t)
(define (leaf name stat result)
(unless (or (string-suffix? ".lock" name)
(survives?))
(unless
(false-if-exception
(begin
(format (current-error-port) "Dropping cache item ~a.~%" name)
(stubs:atomically-update-file
name
lock-file
(lambda (whatever)
#f))))
(format (current-error-port) "Could not clean file ~a.~%" name)))
result)
(define (down name stat result) result)
(define (up name stat result) result)
(define (skip name stat result) result)
(define (error name stat errno result)
(format (current-error-port) "While cleaning the cache: ~a: ~a~%"
name (strerror errno))
result)
(file-system-fold enter? leaf down up skip error 0
(web-cache-dir dir)))
(define (maybe-clean-cache
pc-happen
pc-cleaned
dir)
(when (event? pc-happen)
(clean-cache #:percents pc-cleaned #:dir dir)))
(define (remove-uncacheable-headers response)
(let ((headers (response-headers response)))
(let ((filtered
(filter
(lambda (h)
(case (car h)
((connection keep-alive transfer-encoding)
#f)
(else #t)))
headers)))
(build-response
#:code (response-code response)
#:reason-phrase (response-reason-phrase response)
#:headers filtered
#:port #f))))
(define*-public (add request response response-body
#:key (dir default-cache-dir))
;; Don’t store it if there’s a cache-control no-store
(unless
(let ((cc (response-cache-control response '())))
(assq-ref cc 'no-store))
(set! response (remove-uncacheable-headers response))
(let ((final-file-name (file-name (request-uri request) dir))
(lock-file (lock-file-name dir)))
(maybe-clean-cache 5 5 dir)
(stubs:atomically-update-file
final-file-name
lock-file
(lambda (port)
(write-request request port)
(let ((file-response
(write-response response port)))
(when (string? response-body)
(set! response-body (string->utf8 response-body)))
(when response-body
(write-response-body file-response response-body))
#t))))))
(define (the-current-time)
(time-utc->date
(current-time)))
(define*-public (read uri
#:key
(dir default-cache-dir))
(let ((final-file-name (file-name uri dir)))
(catch 'system-error
(lambda ()
(call-with-input-file final-file-name
(lambda (port)
(let ((request (read-request port)))
(let ((response (read-response port)))
(values request response (read-response-body response)))))))
(lambda error
(format (current-error-port) "Cache miss for ~a: ~s~%"
(uri->string uri)
error)
(values #f #f #f)))))
(define (varies-header? request-a request-b header)
(let ((a (assq-ref (request-headers request-a) header))
(b (assq-ref (request-headers request-b) header)))
(not (equal? a b))))
(define (varies-any-header? request-a request-b headers)
(and (not (null? headers))
(or (varies-header? request-a request-b (car headers))
(varies-any-header? request-a request-b (cdr headers)))))
(define-public (varies? request-a request-b response)
(let ((vary (response-vary response)))
(or (eq? vary '*)
(varies-any-header? request-a request-b vary))))
(define*-public (valid? response
#:key
(current-time the-current-time))
(when (thunk? current-time)
(set! current-time (current-time)))
(when (integer? current-time)
(set! current-time
(make-time time-utc 0 current-time)))
(when (time? current-time)
(set! current-time (time-utc->date current-time)))
(set! current-time
(date->time-utc current-time))
(set! current-time
(time-second current-time))
(let ((cc (response-cache-control response #f))
(date (response-date response
(time-utc->date
(make-time time-utc 0 current-time))))
(last-modified (response-last-modified response)))
(set! date (date->time-utc date))
(set! date (time-second date))
(when last-modified
(set! last-modified (date->time-utc last-modified))
(set! last-modified (time-second last-modified)))
(if cc
;; Use cache-control
(let ((cc-no-cache (assq-ref cc 'no-cache))
(cc-no-store (assq-ref cc 'no-store))
(cc-max-age
(or (assq-ref cc 'max-age)
;; Heuristic freshness
(and last-modified
(/ (- date last-modified) 10)))))
(and (not cc-no-cache)
(not cc-no-store)
cc-max-age
(>= (+ date cc-max-age) current-time)))
;; Use expires
(let ((exp (response-expires response)))
(when exp
(set! exp (date->time-utc exp))
(set! exp (time-second exp)))
(and exp
(>= exp current-time))))))
(define*-public (revalidate uri response body
#:key
(headers '())
(http-get http-get))
(define (keep-header? h)
(case (car h)
((if-none-match if-unmodified-since) #f)
(else #t)))
(let ((etag (response-etag response)))
(if etag
(receive (new-response new-response-body)
(http-get uri
#:headers
(acons 'if-none-match (list etag)
(filter keep-header? headers)))
(if (eqv? (response-code new-response) 304)
(values
(build-response
#:headers
(append
(response-headers new-response)
(filter
(lambda (h)
(case (car h)
((cache-control content-location date etag expires vary)
;; These are overriden by new-response
#f)
(else #t)))
(response-headers response))))
body)
(values new-response new-response-body)))
(http-get uri #:headers headers))))
(define*-public (with-cache
#:key
(current-time the-current-time)
(http-get http-get)
(dir default-cache-dir))
(lambda* (uri #:key (headers '()))
(when (string? uri)
(set! uri (string->uri uri)))
(let ((dir (if (thunk? dir) (dir) dir))
(request (build-request uri #:headers headers)))
(receive (stored-request stored-response body)
(read uri #:dir dir)
(if stored-response
(let ((valid (valid? stored-response #:current-time the-current-time))
(invariant (not (varies? request stored-request stored-response))))
(unless invariant
(format (current-error-port) "Cache entry for ~a varies.\n" (uri->string uri)))
(if (and valid invariant)
(values stored-response body)
(receive (final-response final-body)
(revalidate uri stored-response body
#:headers headers
#:http-get http-get)
(add request final-response final-body #:dir dir)
(values final-response final-body))))
(receive (final-response final-body)
(http-get uri #:headers headers)
(add request final-response final-body #:dir dir)
(values final-response final-body)))))))
|